Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00071_ClickIdentify.ls

Text File | 2004-07-11 | 3.1 KB | 165 lines

--
-- ClickIdentify
--

-- this class handles all runtime game management
-- for a typical C & I Game.
-- for variations, extend this class in the individual activity.

-- constants:
property delaySecs


property ancestor
property currentID

property responseFlag  -- play a response after correct answer
property IDResponseFlag -- play a positive ID sound after clicking correct answer
property currNum  -- the current clickable number in the series
property maxNum   -- the maximum allowable clickables in the series

--JCODE
global gUI

on new me
  -- initialize constants:
  set delaySecs = 1

  set ancestor = new (script "ClickSetUp")

  set card = 0
  set responseFlag = TRUE
  set IDResponseFlag = TRUE
  set currNum = 0
  set maxNum = 1000

  -- add (the actorList, new (script "ObjectUpdater", me))
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


on initializeRound me
  set currNum = 0
  initializeRound (ancestor)
  hideAnswerCards (me)
  initPlay (me)
end


----------------------
-- activity modifiers:
----------------------

--
on noResponse me
  set responseFlag = FALSE
end


on noIDSound me
  set IDResponseFlag = FALSE
end


on setMaxClickables me, num
  set maxNum = num
end


--------------------
-- activity process:
--------------------

-- handle a mouseDown for all activity sprites.
-- return 1 if we have hit an activity sprite, return 0 otherwise for further processing:

on mouseDown me, spr
  if not isClickable (me, spr) then return 0

  set match = checkMatch (me, spr)

  if match then
    if responseFlag then playResponseSound(1, 1)

    -- play the proper "ID" sound:
    if IDResponseFlag then playSprite (gUI, spr, #ID)

    -- if so, move the draggable off the screen and animate the 'hit' container:
    showAnswerCard (me, spr)

    -- get the label of the positive animation and go there if it exists:
    set lab = string (getID (me, spr))


    -- if there is an animation label then play that label:
    if the labelList contains lab then
      clearPictLink (me)
      go lab

      -- otherwise check to see if we are done with the activity:
    else done (me)
  else
    playResponseSound(0, 1)
  end if

  return 1
end


-- check to see if we are done.
-- if so, then do an action.

on done me
  set currNum = currNum + 1
  wait (me, 1)
  clearPictLink (me)
  if checkDone (ancestor) or (currNum >= maxNum) then
    wait (me, delaySecs)
    go "finish"
    return 1
  else
    initPlay (me)
    return 0
  end if
end


on checkDoneLimit me, limit
  set currNum = currNum + 1
  wait (me, 1)
  clearPictLink (me)
  if checkDone (ancestor) or (currNum >= limit) then
    wait (me, delaySecs)
    go "finish"
    return 1
  else
    initPlay (me)
    return 0
  end if
end



-- initialize an individual play:

on initPlay me
  set activeSpr = initPlay (ancestor)
  makePictLink (me, activeSpr)

  -- play the intro sound by sprite...
  playSprite (gUI, activeSpr, #prompt)

  -- setUpBanner(gUI, currID)
  set lst = getClickableList (me)
  initHandCursor ("pointer", lst)
end